请问用perl如何进行邮件直发？

QUOTE:

#!/usr/bin/perl
#
# by Jeff Pang <pangj@earthlink.net>
#
use strict;
use MIME::Lite;
use MIME::Words qw/:all/;
use Email::Valid;
require 'config.txt';

our $content = slurp('template.html');
our %config;
our $subject = $config{subject};
our $sender_name = $config{sender_name};
our $sender_email = $config{sender_email};

$subject = encode_mimeword($subject,'b','gb2312');
$sender_name = encode_mimeword($sender_name,'b','gb2312');

my $recepients = get_recepient('email.txt');

for my $to (@$recepients) {
    sendmail($to);
}

sub sendmail {

    my $to = shift;

    my $msg = MIME::Lite->new(
        From    => "$sender_name <$sender_email>",
        To      => $to,
        Subject => $subject,
        Type    => 'text/html',
        Encoding => 'base64',
        Data    => $content,
    );

    $msg->attr('content-type.charset' => 'gb2312');
    $msg->send('smtp','127.0.0.1', Debug=>0);
}

sub slurp {

    my $file = shift;

    local $/;
    open HD,$file or die $!;
    my $c = <HD>;
    close HD;

    return $c;
}

sub get_recepient {
   
    my $file = shift;
    my @addr;

    open HD,$file or die $!;
    while(<HD>) {
        s/^\s+|\s+$//g;
        next if /^$/;
        next unless Email::Valid->address($_);
        push @addr,$_;
    }
    close HD;

    return \@addr;
}

QUOTE:

%config = (
    sender_email => 'cs@abc-online.com',
    sender_name  => 'ABC客服',
    subject      => 'ABC群发邮件',
);

1;

QUOTE:

test@aol.com   
test@163.com   
test@yahoo.com